Étape 5: anti-aliasing et source lumineuse étendue
On utilise cette fois-ci une source lumineuse étendue spatialement, ce qui donne des zones de pénombre à la limite des ombres portées, au lieu des transitions brusques obtenues avec une source ponctuelle. On a aussi activé un système de sur-échantillonnage adaptif qui supprime les effets de crênelage sur les lignes obliques.Fichier : examples/scene5.pov #include "colors.inc"
#include "golds.inc"
#include "metals.inc"
#include "woods.inc"
#include "glass.inc"
#include "stones.inc"
#include "skies.inc"
global_settings{
max_trace_level 10
}
camera{
location <4,2,6>
right 1.3*x
look_at <0,-1.5,0>
angle 40
}
merge{
sphere{
<0,0.5,0>,0.3
}
superellipsoid{
<0.5,0.5>
scale <0.3,1.3,0.3>
translate <0,-1.3,0>
rotate <0,30,0>
}
cylinder{
0,<0,0.5,0>,0.1
}
translate <1.8,0,0.6>
texture{
pigment{color Clear}
}
finish{
F_Glass5
}
interior{
I_Glass_Caustics2 fade_color Col_Orange
}
}
superellipsoid{
<0.3,0.2>
translate y
scale 0.4
translate -2*y
rotate <0,70,0>
translate <1,0,-0.5>
texture{
T_Wood30
rotate <15,10,5>
translate x
finish{
ambient 0.4
}
}
}
sphere{
<-1,-1.6,0.2>,0.4
texture{
T_Gold_1C
normal{
bumps 0.2 scale 0.04
}
}
}
sphere{
<-1,-1.4,1.8>,0.6
texture{
T_Chrome_1E
}
}
box{
-1,1
translate y
scale 0.3
translate -2*y
rotate <0,10,0>
translate <1,0,1.8>
texture{
T_Silver_1C
normal{
facets coords 0.03 scale 0.6
}
}
}
intersection{
plane{
y,-2
}
box{
<-2.5,-10,-2.5>,<2.5,4,2.5>
}
texture{
T_Stone5
finish{
diffuse 0.8
ambient 0.1
reflection 0.2
}
normal{
dents 0.3
scale 0.7
}
}
}
light_source {
10,color 1.5
area_light <-1,1,0>,<-1,0,1>,5,5
adaptive 1
circular
jitter
}
sky_sphere{S_Cloud1} Ce document a été traduit de LaTeX par HeVeA |