#include "colors.inc"

#declare T_Pierre =
  texture {
    normal { brick -0.04 mortar 0.1 }
    pigment {
      granite
      color_map {
	[0 Gray60]
	[1 Gray80]
      }
    }
    scale 0.2
  }

#declare F_Marbre =
  finish {
    reflection 0.3
    specular 0.4
    roughness 0.01
  }

#declare T_Marbre_Rose =
  texture {
    pigment {
      granite
      turbulence 1.0
      color_map {
        [0.0 color rgb <1.0,0.4,0.4>]
        [0.3 color rgb <1.0,0.4,0.5> ]
        [0.4 color rgb <0.7,0.1,1.0> ]
        [0.5 color rgb <1.0,0.6,0.5> ]
        [0.6 color rgb <1.0,0.6,0.4> ]
      }
    }
    finish { F_Marbre }
    scale <1,3,1>
  }

#declare T_Marbre_Rouge =
  texture {
    pigment {
      granite
      turbulence 1.0
      color_map {
        [0.0 color rgb <1.0,0.0,0.0>]
        [0.3 color rgb <0.7,0.0,0.0> ]
        [0.4 color rgb <0.7,0.3,0.0> ]
        [0.5 color rgb <0.3,0.0,0.0> ]
        [0.6 color rgb <0.7,0.0,0.3> ]
      }
    }
    finish { F_Marbre }
    scale 3
  }

#declare T_Marbre_Noir =
  texture {
    pigment {
      granite
      turbulence 1.0
      color_map {
        [0.0 color rgb <0.0,0.0,0.0>]
        [0.2 color rgb <0.1,0.1,0.1> ]
        [0.3 color rgb <0.0,0.0,0.0> ]
        [0.4 color rgb <0.2,0.2,0.2> ]
        [0.5 color rgb <0.0,0.0,0.0> ]
      }
    }
    finish { F_Marbre }
    scale 3
  }

#declare Murs =
  union {
    intersection {
      union {
	box { <-6.5,4,-6.5>, <6.5,6,6.5> }
	box { <-6.5,0,-6.5>, <6.5,1,6.5> }
      }
      box { <-5.5,-1,-5.5>, <5.5,7,5.5> inverse }

      quadric { <-1,-4,0>, 0, 0, 2.25 translate <-4,4,0> }
      quadric { <-1,-4,0>, 0, 0, 2.25 translate < 0,4,0> }
      quadric { <-1,-4,0>, 0, 0, 2.25 translate < 4,4,0> }

      quadric { <0,-4,-1>, 0, 0, 2.25 translate <0,4,-4> }
      quadric { <0,-4,-1>, 0, 0, 2.25 translate <0,4, 0> }
      quadric { <0,-4,-1>, 0, 0, 2.25 translate <0,4, 4> }
    }

    plane { -z, -6.5 }
    plane {  z, -6.5 }
    plane { -x, -6.5 }
    plane {  x, -6.5 }
    plane { -y, -5 }

    texture { T_Pierre }
  }

#declare Sol =
  plane {
    y, 0
    texture {
      checker
      texture { T_Marbre_Rouge }
      texture { T_Marbre_Noir }
      translate <0.5,0,0.5>
      scale 2.2
    }
  }

#declare Colonne =
  union {
    quadric { <1,0,1>, 0, 0, -0.09 }
    torus { 0.3, 0.08 translate 1*y }
    torus { 0.3, 0.08 translate 4*y }
    torus { 0.3, 0.03 translate 1.08*y }
    torus { 0.3, 0.03 translate 3.92*y }
    bounded_by { box { <-0.4,0,-0.4>, <0.4,4,0.4> } }
  }

#declare Colonnes =
  union {
    object { Colonne translate <-6,0,-6> }
    object { Colonne translate <-2,0,-6> }
    object { Colonne translate < 2,0,-6> }
    object { Colonne translate < 6,0,-6> }
    object { Colonne translate < 6,0,-2> }
    object { Colonne translate < 6,0, 2> }
    object { Colonne translate < 6,0, 6> }
    object { Colonne translate < 2,0, 6> }
    object { Colonne translate <-2,0, 6> }
    object { Colonne translate <-6,0, 6> }
    object { Colonne translate <-6,0, 2> }
    object { Colonne translate <-6,0,-2> }
    texture { T_Marbre_Rose }
  }

object { Murs }
object { Sol }
object { Colonnes }

light_source { < 2,3,-5> Gray25 }
light_source { < 5,3, 2> Gray25 }
light_source { <-2,3, 5> Gray25 }
light_source { <-5,3,-2> Gray25 }

camera {
  location <4,2.5,-6.4>
  look_at <0,2.5,0>
}