Counting rooted planar quadrangulations

2. The functional equation in polynomial form

P[Q_,q_,t_,u_]=Factor[u(Q-1- u (Q^2)-t ((Q-1-u q)/u))]

3. Differentiating with respect to Q

Derivative[1,0,0,0][P][Q[U],(Subscript[Q, 1]),t,U]==0

Existence of a solution : this equation amounts to U=t+2 (U^2) Q[U] which has a unique solution by a fixed-point argument

4. The two other equations

Derivative[0,0,0,1][P][Q[U],(Subscript[Q, 1]),t,U]==0
P[Q[U],(Subscript[Q, 1]),t,U]==0

5. Manipulation of the polynomial system

We first express Q[U] in terms of U by the first equation

Solve[Derivative[1,0,0,0][P][Q[U],(Subscript[Q, 1]),t,U]==0,Q[U]][[1]]

We then substitute in the second equation and solve for (Subscript[Q, 1])

Solve[(Derivative[0,0,0,1][P][Q[U],(Subscript[Q, 1]),t,U]==0)/.{Q[U]->((-t+U)/(2 (U^2)))},(Subscript[Q, 1])][[1]]

Finally we substitute all this in the third equation and solve for U (and pick the correct determination)

Factor[P[Q[U],(Subscript[Q, 1]),t,U]==0/.{Q[U]->((-t+U)/(2 (U^2))),(Subscript[Q, 1])->(((t^2)-t U+2 (U^3))/(2 t (U^3)))}]
Simplify[Solve[%,U],Assumptions->t>0][[1]]

And now we plug this in (Subscript[Q, 1]), and compute the first few terms

FullSimplify[{(Subscript[Q, 1])->(((t^2)-t U+2 (U^3))/(2 t (U^3)))}/.{U->-(((-2+(Sqrt[1-12 t])) t)/(1+4 t))},Assumptions->t>0]
Series[(Subscript[Q, 1])/.%,{t,0,10}]

Compare with the explicit formula

Table[((2 (3^n) (2n)!)/(n!(n+2)!)),{n,0,10}]

6. Rational parametrization

We return to our quadratic equation relation U and perform the substitution

Solve[((3 (t^2)-4 t U+(U^2)+4 t (U^2))/(4 (U^2)))==0/.U->((R-1)/(R(2+R))),t][[1]]
Simplify[{(Subscript[Q, 1])->(((t^2)-t U+2 (U^3))/(2 t (U^3)))}/.{U->((R-1)/(R(2+R)))}/.%]

7. Returning to the initial functional equation and computing the discriminant

funQRu=Factor[P[Q,(Subscript[Q, 1]),t,u]/.{t->((-1+R)/(3 (R^2))),(Subscript[Q, 1])->-(1/3) (-4+R) R}]
Factor[Discriminant[%,Q]]

Notice the square factor

8. The one-cut form

We simply check the announced form now

Qonecut:=(((1-R+3 (R^2) u)-(1-R+2 R u+(R^2) u)Sqrt[1-4R u])/(6 (R^2) (u^2)))
Simplify[funQRu/.Q->Qonecut]

9. Expansion in u

Series[Qonecut,{u,0,10}]
%-Sum[(((2+R)CatalanNumber[k]+(1-R)CatalanNumber[k+1])/3)(R^k) (u^k),{k,0,10}]

Basketball walks

Kernel and right-hand side

K[t_,u_]:=1-t((u^(-2))+(u^(-1))+u+(u^2))
R[t_,u_]:=t(1+ u)-(t/u) ((Subscript[G, 1])+(Subscript[G, 2])+((Subscript[G, 1])/u))

The initial terms as functions of the roots

Solve[{R[t,(Subscript[U, 1])]==0,R[t,(Subscript[U, 2])]==0},{(Subscript[G, 1]),(Subscript[G, 2])}]

Actually we may write (Subscript[G, 1]) as a polynomial in the symmetric functions (Subscript[e, 1])=(Subscript[U, 1])+(Subscript[U, 2]), (Subscript[e, 2])=(Subscript[U, 1])(Subscript[U, 2])

SymmetricReduction[(Subscript[G, 1])/.%[[1]],{(Subscript[U, 1]),(Subscript[U, 2])},{(Subscript[e, 1]),(Subscript[e, 2])}][[1]]

Series expansion of (Subscript[U, 1,2]), here τ = (t^(1/2)) or -(t^(1/2))

InverseSeries[Series[u/Sqrt[1+u+(u^3)+(u^4)],{u,0,20}]/.u->τ]

An algebraic equation for (Subscript[G, 1])

Notice that the equation K[t,U]=0 can be rewritten as the system
X=U+1/U
1=t((X^2)+X-2)
The second equation admits two roots (Subscript[X, 1]) and (Subscript[X, 2]), and it is not difficult to check that each of them fixes one of the (Subscript[U, i])

(Subscript[X, 1]):=(Subscript[U, 1])+1/(Subscript[U, 1])
(Subscript[X, 2]):=(Subscript[U, 2])+1/(Subscript[U, 2])
(* since (Subscript[X, 1]) and (Subscript[X, 2]) are the two roots of (X^2)+X-2-1/t, we have (Subscript[X, 1])(Subscript[X, 2])=-2-1/t and (Subscript[X, 1])+(Subscript[X, 2])=-1 *)
(* but (Subscript[X, 1])(Subscript[X, 2]) and (Subscript[X, 1])+(Subscript[X, 2]) are also symmetric functions in (Subscript[U, 1]) and (Subscript[U, 2]), hence polynomials in (Subscript[e, 1])=(Subscript[U, 1])+(Subscript[U, 2]), (Subscript[e, 2])=(Subscript[U, 1])(Subscript[U, 2]) *)
(* so we deduce a system of two polynomial equations for (Subscript[e, 1]) and (Subscript[e, 2]) *)
Numerator[Factor[(Subscript[X, 1]) (Subscript[X, 2])+2+1/t]];
SymmetricReduction[%,{(Subscript[U, 1]),(Subscript[U, 2])},{(Subscript[e, 1]) ,(Subscript[e, 2])}][[1]]==0
Numerator[Factor[(Subscript[X, 1]) +(Subscript[X, 2])+1]];
SymmetricReduction[%,{(Subscript[U, 1]),(Subscript[U, 2])},{(Subscript[e, 1]) , (Subscript[e, 2])}][[1]]==0

Since (Subscript[G, 1])=-(Subscript[e, 2])-(Subscript[e, 1]) (Subscript[e, 2]),  we obtain by elimination an algebraic equation for (Subscript[G, 1]) which admits a unique “good” solution, whose expansion yields the wanted numbers

Eliminate[{t+t (Subscript[e, 1]^2)+(Subscript[e, 2])+t (Subscript[e, 2]^2)==0,(Subscript[e, 1])+(Subscript[e, 2])+(Subscript[e, 1]) (Subscript[e, 2])==0,(Subscript[G, 1])==-(Subscript[e, 2])-(Subscript[e, 1]) (Subscript[e, 2])},{(Subscript[e, 1]),(Subscript[e, 2])}]

Solve[%,(Subscript[G, 1])][[2]]
FullSimplify[Series[(Subscript[G, 1])/.%,{t,0,10}],Assumptions->t>0]

And Catalan numbers at the end

FullSimplify[(1+(Subscript[G, 1])+((Subscript[G, 1])^2))/.(Subscript[G, 1])->(1/2) (-1+(Sqrt[-3+(2/t)-((2 (Sqrt[1-4 t]))/t)]))]